8254定时/计数器应用实验

实验目的：

1.掌握8254的工作方式及应用编程。

2.掌握8254典型应用电路的接法。

二、实验环境：

PC机一台，TD-PITD实验装置一套，示波器一台。

三、实验内容：

计数应用实验。编写程序，应用8254的计数功能，使用单次脉冲模拟计数，使每当按动‘KK1+’5次后，产生一次计数中断，并在屏幕上显示一个字符‘5’。

2.定时应用实验。编程程序，应用8254的定时功能，产生一个1Hz的方波。

实验步骤

1. 计数应用实验

编写程序，将 8254 的计数器 0 设置为方式 3，计数值为十进制数 4，用单次脉冲 KK1＋作为 CLK0 时钟，OUT0 连接 INTR，每当 KK1＋按动 5 次后产生中断请求，在屏幕上显示字符“5”。实验步骤如下：

实验接线图如图 3-3-3 所示，按图连接实验线路图。
根据实验内容，编写实验程序，编译、链接

;T8254-1.asm

;查看端口资源分配情况，记录实验系统I/O端口始地址

INTR_IVADD     EQU   003CH        ;INTR对应的中断矢量地址

IOY0           EQU   0A000H        ;片选IOY0对应的端口始地址
MY8254_COUNT0  EQU   IOY0+00H*2   ;8254计数器0端口地址
MY8254_COUNT1  EQU   IOY0+01H*2   ;8254计数器1端口地址
MY8254_COUNT2  EQU   IOY0+02H*2   ;8254计数器2端口地址
MY8254_MODE    EQU   IOY0+03H*2   ;8254控制寄存器端口地址
                              
STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT 
CS_BAK   DW  ?                    ;保存INTR原中断处理程序入口段地址的变量
IP_BAK   DW  ?                    ;保存INTR原中断处理程序入口偏移地址的变量
IM_BAK   DB  ?                    ;保存INTR原中断屏蔽字的变量
STR1     DB  'COUNT: $'           ;显示的字符串
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       CLI

       MOV AX,0000H               ;替换INTR的中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD          
       MOV AX,ES:[DI]
       MOV IP_BAK,AX              ;保存INTR原中断处理程序入口偏移地址
       MOV AX,OFFSET MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口偏移地址

       ADD DI,2
       MOV AX,ES:[DI]
       MOV CS_BAK,AX              ;保存INTR原中断处理程序入口段地址
       MOV AX,SEG MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口段地址

       IN  AL,21H
       MOV IM_BAK,AL              ;保存INTR原中断屏蔽字
       AND AL,7FH
       OUT 21H,AL

       STI
       MOV DX,OFFSET STR1         ;显示字符串
       MOV AH,9
       INT 21H

       MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,10H                 ;计数器0，方式0  
       OUT DX,AL             

       MOV DX,MY8254_COUNT0       ;装入计数初值
       MOV AL,4
       OUT DX,AL

WAIT1: MOV AH,1                   ;判断是否有按键按下
       INT 16H
       JZ  WAIT1                  ;无按键则跳回继续等待，有则退出

QUIT:  CLI

       MOV AX,0000H               ;恢复INTR原中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD  
       MOV AX,IP_BAK              ;恢复INTR原中断处理程序入口偏移地址
       MOV ES:[DI],AX
       ADD DI,2
       MOV AX,CS_BAK              ;恢复INTR原中断处理程序入口段地址
       MOV ES:[DI],AX

       MOV AL,IM_BAK              ;恢复INTR原中断屏蔽寄存器的屏蔽字
       OUT 21H,AL
       STI

       MOV AX,4C00H               ;返回到DOS
       INT 21H

MYISR PROC NEAR                   ;中断处理程序MYISR
       PUSH AX
       MOV AL,35H
       MOV AH,0EH
       INT 10H
       MOV AL,20H
       INT 10H

       MOV DX,MY8254_COUNT0       ;重装计数初值
       MOV AL,4
       OUT DX,AL

OVER:  MOV AL,20H                 ;向PC机内部8259发送中断结束命令
       OUT 20H,AL
       POP AX
       IRET
       
MYISR ENDP
       
CODE ENDS
     END START

运行程序，按动 KK1＋产生单次脉冲，观察实验现象。

改变计数值，验证 8254 的计数功能。

计数应用实验接线图

2. 定时应用实验

编写程序，将8254的计数器2设置为方式3，用信号源1.8432MHz作为CLK1 时钟，计数初值为 100，相对于 CLK1 进行 100 分频。在 OUT1 输出频率为 18.432MHz 的时钟。将 OUT1 连接到计数器 0 的 CLK0，设置计数器 0 工作在方

式 3，计数初值为 18432，相当是进行 18432 分频。则在 OUT0 得到 1Hz 的输出。

实验接线图如图 3-3-4 所示，按图连接实验线路图。

根据实验内容，编写实验程序，编译、链接。

;T8254-2.asm
;8254定时应用实验  输出1Hz

;查看端口资源分配情况，记录实验系统I/O端口始地址

;****************根据查看端口资源修改下列符号值*******************
IOY0           EQU   0A000H         ;片选IOY0对应的端口始地址
;*****************************************************************
MY8254_COUNT0  EQU   IOY0+00H*2   ;8254计数器0端口地址
MY8254_COUNT1  EQU   IOY0+01H*2   ;8254计数器1端口地址
MY8254_COUNT2  EQU   IOY0+02H*2   ;8254计数器2端口地址
MY8254_MODE    EQU   IOY0+03H*2   ;8254控制寄存器端口地址
                              
STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

CODE SEGMENT
        ASSUME CS:CODE

START: MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,76H                 ;计数器1，方式3
       OUT DX,AL
                
       MOV DX,MY8254_COUNT1       ;装入计数初值
       MOV AL,64H                 ;100分频
       OUT DX,AL
       MOV AL,00H
       OUT DX,AL

       MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,36H                 ;计数器0，方式3
       OUT DX,AL
                
       MOV DX,MY8254_COUNT0       ;装入计数初值
       MOV AL,00H                 ;18432分频
       OUT DX,AL 
       MOV AL,48H
       OUT DX,AL
       
QUIT:  MOV AX,4C00H               ;结束程序退出
       INT 21H
       
CODE ENDS
     END START